root/trunk/irssi/irssi2jabber.pl

#!/usr/bin/perl
#
# Sends a message to jabber if a hilight occurs in irssi.
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
#
# Add config to your irssi configuration in the following style:
#
#   settings = {
#       "perl/core/scripts" = {
#           irssi2jabber_server = "yourserver.com";
#           irssi2jabber_port = "5222";
#           irssi2jabber_user = "youruser";
#           irssi2jabber_password = "yourpassword";
#           irssi2jabber_resource = "yourresource";
#           irssi2jabber_dest = "alias@yourdestination.com";
#           irssi2jabber_awayonly = 1;
#       };
#   };
#
# "port" and "resource" may be left out. The ports defaults to 5222 and
# the resource default is "irssi".
#
# See also http://blog.antiblau.de/2008/07/10/irssi-hilight-mit-jabber/

use strict;
use warnings;

use Net::Jabber;
use Irssi;
use Encode;

use vars qw($VERSION %IRSSI);

$VERSION='0.4';
%IRSSI = (
    authors => 'Stefan Haun',
    contact => 'mail\@tuxathome.de',
    name => 'irssi2jabber.pl',
    description => 'Send irssi hilights and privmsgs to jabber.',
    license => 'GPLv3');

# Register settings
Irssi::settings_add_str('misc', 'irssi2jabber_server', '');
Irssi::settings_add_str('misc', 'irssi2jabber_port', '5222');
Irssi::settings_add_str('misc', 'irssi2jabber_user', '');
Irssi::settings_add_str('misc', 'irssi2jabber_password', '');
Irssi::settings_add_str('misc', 'irssi2jabber_resource', 'irssi');
Irssi::settings_add_str('misc', 'irssi2jabber_destination', '');
Irssi::settings_add_bool('misc', 'irssi2jabber_awayonly', 1);

# Trap signals which are emitted on interesting messages
Irssi::signal_add('message private', 'trap_privmsg');
Irssi::signal_add('print text', 'trap_hilight');

## Called when a hilighted message is print out
#
# Adheres to the irssi declaration for this signal

sub trap_hilight {
    my ($dest, $text, $stripped) = @_;
    my $server = $dest->{server};
    my ($hilight) = Irssi::parse_special('$;');

    # only highlighted messages/actions  
    return if (!$server || !($dest->{level} & MSGLEVEL_HILIGHT) || 
        ($dest->{level} & (
                            MSGLEVEL_MSGS|MSGLEVEL_NOTICES|MSGLEVEL_SNOTES|
                            MSGLEVEL_CTCPS|MSGLEVEL_JOINS|
                            MSGLEVEL_PARTS|MSGLEVEL_QUITS|MSGLEVEL_KICKS|
                            MSGLEVEL_MODES|MSGLEVEL_TOPICS|MSGLEVEL_WALLOPS|
                            MSGLEVEL_INVITES|MSGLEVEL_NICKS|MSGLEVEL_DCC|
                            MSGLEVEL_DCCMSGS|MSGLEVEL_CLIENTNOTICE|
                            MSGLEVEL_CLIENTERROR    
                          )
        )
    );

    # only if in away mode
    if (!Irssi::settings_get_bool('irssi2jabber_awayonly') 
        || $server->{usermode_away}) {
        &send_message("Hilight from $hilight in $dest->{target} " .
            "on $server->{chatnet}", $stripped);
    }
}

## Called when a private message has been received
#
# Adheres to the irssi declaration for this signal

sub trap_privmsg {
    my ($server, $msg, $nick, $address) = @_;

    # only if in away mode
    if (!Irssi::settings_get_bool('irssi2jabber_awayonly') 
        || $server->{usermode_away}) {
        &send_message("Private message from $nick on $server->{chatnet}", $msg);
    }
}

## Send a message to the designated jabber account
#
# Since connecting to the jabber server for simple message dispatching
# is quite fast, the connection is established for every message. This
# is simpler than managing persistent connection, which may be broken
# or outdated due to configuration changes.
# 
# Parameters:
#   1. $subject     The message subject
#   2. $body        The message body
#
# Prints an error message to the irssi console if something goes wrong.

sub send_message {
    my ($subject, $body) = @_;

    my $conn = Net::Jabber::Client->new();
    $conn->Connect( 
        "hostname" => Irssi::settings_get_str('irssi2jabber_server'),
        "port" => Irssi::settings_get_str('irssi2jabber_port')
    ) or do {
        Irssi::print "Cannot connect: $!\n";
        return;
    };

    my @result = $conn->AuthSend( 
        "username" => Irssi::settings_get_str('irssi2jabber_user'),
        "password" => Irssi::settings_get_str('irssi2jabber_password'),
        "resource" => Irssi::settings_get_str('irssi2jabber_resource') 
    );

    if ($result[0] ne 'ok') {
        Irssi::print "Auth failed: $result[0] - $result[1]\n";
        return;
    }

    # assuming irssi has no perl strings but binary strings
    # and Net::Jabber requires decoded perl strings
    my $irssitermenc = Irssi::settings_get_str('term_charset');
    if (Encode::resolve_alias($irssitermenc) eq 'ascii')
    {
        $irssitermenc = Irssi::settings_get_str('recode_fallback');
    }
    $conn->MessageSend( 
        'to' => Irssi::settings_get_str('irssi2jabber_destination'), 
        'subject' => decode($irssitermenc, $subject), 
        'body' => decode($irssitermenc, $body)
    );

    $conn->Disconnect();
}

# End of Script